Detailed Description

The CDPBaseComObj class is used for communication with CDP in C++ and QML.

Usage in C++

Example showing how to receive values from a CDP object:

CDPBaseComObj *pObj = new CDPBaseComObj;
pObj->setScalingFactor(1.0);
pObj->setRouting("Application.Component.Signal.Value");
connect(pObj, SIGNAL(valueChanged(double)), this, SLOT(handleValue(double)));

Example showing how to change the value of a remote CDP object:

CDPBaseComObj *pObj = new CDPBaseComObj;
pObj->setRouting("Application.Component.Signal.Value");
...
pObj->SetValueDouble(2.0)

Example showing how to send a message with parameter to a CDP object:

CDPBaseComObj *pObj = new CDPBaseComObj;
pObj->setCommand("Select");
pObj->setParameter("DTWinch");
pObj->setRouting("Application.Component");
...
pObj->sendMsg()

Usage in QML

Example showing how to register the object for use in QML:

#include <qqml.h>
#include <CDPBaseWidgets/CDPBaseComObj.h>

int main (int argc, char* argv[])
{
  ...
  QApplication app(argc, argv);
  qmlRegisterType<CDPBaseComObj>("CDP2Qt", 1, 0, "CDPBaseComObj");
  ...

Example showing how to update QML texts when registerred as above. The value changed handlers are not strictly needed. They were added to show how objects can get updated, not only by requesting data, but also by push from the com object. Both methods will update the texts when new values are received.

import QtQuick 2.0
import CDP2Qt 1.0

Item {
  CDPBaseComObj {
    id: amplitude
    routing: "App.Sine.Amplitude.Value"

    stringPrecision: 3
    scaling: 1.0

    onStringValueChanged: {
      console.log("StringValue = " + stringValue)
    }
    onValueChanged: {
      console.log("Value = " + value)
      text2.text = "Value = " + value
    }
    onConnectionStateChanged: {
        console.log("Connection = " + connected)
    }
  }
  Text {
    id: text1
    anchors.centerIn: parent
    text: "Value = " + amplitude.value
  }
  Text {
    id: text2
    anchors.top: text1.bottom; anchors.horizontalCenter: text1.horizontalCenter;
    text: "Value = 0"
  }
  Text {
    id: text3
    anchors.top: text2.bottom; anchors.horizontalCenter: text1.horizontalCenter;
    text: "Connection = " + amplitude.connected
  }
}

Example showing how to send messages in QML. The first text shows whether or not the Sine component of App is suspended and the value of the Sine Output. The second text can be clicked to send text commands to the component to make it suspended or active.

import QtQuick 2.0
import CDP2Qt 1.0

Item {
  CDPBaseComObj { id: comOutput; routing: "App.Sine.Output.Value"; stringPrecision: 3}
  CDPBaseComObj { id: comSine;  routing: "App.Sine"; command: "CM_SUSPEND"; }
  CDPBaseComObj { id: comSuspended;  routing: "App.Sine.Suspended"; }

  Text {
    id: text1
    anchors.centerIn: parent
    property string sineState: comSuspended.value==1 ? "Yes" : "No"
    text: "Suspended: " + sineState + ", Output: " + comOutput.stringValue
  }
  Text {
    id: text2
    anchors.top: text1.bottom; anchors.horizontalCenter: text1.horizontalCenter;
    text: "Click to toggle Sine suspended!"
  }
  MouseArea {
    anchors.fill: text2;
    onPressed: {
      if (comSuspended.value == 1){
        comSine.command = "CM_ACTIVATE"
        comSine.sendMsg()
      }
      else {
        comSine.command = "CM_SUSPEND"
        comSine.sendMsg()
      }
    }
  }
}